基于ESP8266芯片的实时温湿度传感器

准备工作：

1. ESP8266芯片

2. DHT11温湿度传感器

3. 点灯科技平台

一. 电路设计

以ESP8266连接手机终端，以DHT11为数据发送端，将DHT11的三个接口分别接在ESP8266芯片的3V、G以及D7引脚（自定义）上。3V、G对应于DHT11上的正负极，D7引脚主要接收由DHT11传输来的数据，最后由ESP8266芯片的WIFI模块将数据上传到手机终端，供用户接收查看

二. 代码设计

将代码用 arduino 软件烧录到ESP8266上


#define BLINKER_WIFI

#include <Blinker.h>

char auth[] = "737426fbeb6a";     //点灯科技密钥
char ssid[] = "aoaodadie";        //连接的WIFI名称
char pswd[] = "jaashiwoer.";      //连接WIFI的密码

BlinkerNumber HUMI("humi");       //对应手机上的显示框1对应湿度
BlinkerNumber TEMP("temp");       //对应手机上显示框2对应温度

// Download Adafruit DHT-sensor-library library here:
// https://github.com/adafruit/DHT-sensor-library
#include <DHT.h>

#define DHTPIN 13             //对应esp8266引脚D7

#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

DHT dht(DHTPIN, DHTTYPE);

uint32_t read_time = 0;

float humi_read, temp_read;

void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);

    Blinker.vibrate();
    
    uint32_t BlinkerTime = millis();
    
    Blinker.print("millis", BlinkerTime);
}

void heartbeat()
{
    HUMI.print(humi_read);
    TEMP.print(temp_read);
}

void setup()
{
    Serial.begin(9600);
    BLINKER_DEBUG.stream(Serial);

    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, LOW);

    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
    Blinker.attachHeartbeat(heartbeat);
    
    dht.begin();
}

void loop()
{
    Blinker.run();

    if (read_time == 0 || (millis() - read_time) >= 2000)
    {
        read_time = millis();

        float h = dht.readHumidity();
        float t = dht.readTemperature();        

        if (isnan(h) || isnan(t)) {
            BLINKER_LOG("Failed to read from DHT sensor!");
            return;
        }

        float hic = dht.computeHeatIndex(t, h, false);

        humi_read = h;
        temp_read = t;

        BLINKER_LOG("Humidity: ", h, " %");
        BLINKER_LOG("Temperature: ", t, " *C");
        BLINKER_LOG("Heat index: ", hic, " *C");
    }
}

三. 上传到云端

在手机上安装点灯科技，在ESP8266芯片接入传感器DHT11模块后，将ESP8266芯片接入电脑，使用Arduino软件进行代码的上传和烧录，等待DHT11将数据传输给ESP8266芯片，在通过WIFI模块将数据上传至手机上，实现对温湿度的直观观测。下面是不同时间温湿度的直观变化情况：