首页 » 单片机 » 正文
单片机

基于Arduino IDE平台开发ESP8266通过MQTT连接ONENET

Arduino教程传送门🧭🏔🌋🛤🏞🏜

1. 简介

ESP8266-NodeMCU的环境配置已经在一篇文章有所交代，接下让我们开启ONENET的MQTT物联网开发吧！😀😀😀

设计目标

  1. 实现可以通过WIFI_DEBUG选择是使用一键配网功能还是使用代码中写入的无线账号密码连接；
  2. 实现ESP8266通过MQTT协议连接ONENET；
  3. 实现DHT11温湿度数据的获取，串口发送调试，并将数据上发ONENET平台，于平台控件中显示数据；
  4. 实现ONENET平台对ESP8266板载LED亮灭的控制。
  5. 实现ONENET平台温度限幅触发器提示。

2. 实验准备

实验准备包括硬件和软件两部分。

2.1 硬件

你要实现用ESP 8266+ONENET物联网你需要准备以下材料

  1. ESP8266-NodeMCU单片机（外加安卓数据线）；
  2. DHT11温湿度传感器；
  3. 三根母母杜邦线；
    在这里插入图片描述

2.2 软件

  1. Arduino IED 1.8.5以上(越高越好)；
  2. 必须添加PubSubClient、ArduinoJson、dht11库，有空大家可以仔细读里面的例程；
  3. 浏览器登录onenet平台。
    在这里插入图片描述

3. 实验步骤

首先搭建onenet平台，记录对应创建的产品相关参数，以便后期程序端口接入开发。👩👩👩

3.1 搭建onenet监控平台

  1. 登录onenet平台，选择控制台🎈
    在这里插入图片描述

  2. 来到控制台首页，选择全部产品服务，采用多协议接入🎈🎈
    在这里插入图片描述

  3. 进入多协议界面，选择MQTT（旧版），然后添加产品，以此根据实际需求填写，点击确认完成产品创建🎈🎈🎈
    产品简介

通过MQTT协议实现onenet平台物联网开发，
主要功能实现DHT11数据透传
采用控件实现MCU板载LED开与关

在这里插入图片描述

  1. 立即添加设备，完善相关信息，点击添加完成设备添加🎈🎈🎈🎈
    在这里插入图片描述
    在这里插入图片描述
  2. 这样就添加产品和设备都完成了，然后点击详情🎈🎈🎈🎈🎈
    在这里插入图片描述
  3. 敲黑板，重头戏来了，添加APIKey，点击提交，接入onenet需要基础的三个参数，依次记录第一参数设备ID，第二个参数是APIKey
    在这里插入图片描述
    在这里插入图片描述
    选择产品概况，记录第三个参数产品ID

在这里插入图片描述
大家复制自己的，用我的参数将直接导致实验失败！！！✨✨✨

设备ID：806063435
APIKey：a5mVerZDERoRx54Mbehwczm3BF4= 
产品ID：466556

3.2 为ESP8266-NodeMCU烧入程序

  1. 硬件连接，ESP8266-NodeMCU硬件连接非常简单，只需将DHT11数据线接入D6引脚就好，具体接线如下
ESP8266-NodeMCU -----> USBtoTLL
VCC -----> 3.3V 
GND -----> GND
out -----> D6

在这里插入图片描述
2. 程序设计，程序有三部分esp8266_mqtt、OneNet和smartConfig，其中：

文件名 功能
esp8266_mqtt 程序初始化调用和主程序调用；
OneNet 初始化系统、连接OneNet、云端下发、发布温湿度信息
smartConfig 自动连接、一键配网、延时重启

在这里插入图片描述

esp8266_mqtt代码如下，只需要修改对应的wifi和onenet的三个参数；

/**
   The blue LED on the ESP-01 module is connected to GPIO1
   1.实现ESP8266通过MQTT协议连接ONENET
   2.实现DHT11温湿度数据的获取，串口发送调试，并将数据上发ONENET平台，于平台控件中显示数据
   3.实现ONENET平台对ESP8266板载LED亮灭的控制
   4.实现可以通过WIFI_DEBUG选择是使用一键配网功能还是使用代码中写入的无线账号密码连接，该功能主要考虑程序的通用性
   @author 234vor参考https://blog.csdn.net/weixin_43278295/article/details/114900553
   @date 2021/10/30
*/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>
#include <Ticker.h>
#include <dht11.h>

#define WIFI_DEBUG 1          //1：使用一键配网，其它值则使用默认无线账号密码
#define DHT11PIN 12           //设置DHT引脚为Pin 12（D6）
#define ONENET_DISCONNECTED 1 //已经断开
#define ONENET_CONNECTED 2    //已经连接上
#define ONENET_RECONNECT 3    //重连成功
#define VER  "ESP8266_MQTT_V1.0"  //版本号

#define AP_SSID "J09 502" //需要修改你的wifi名字
#define AP_PSW  "qwertyuiop111"//需要修改你的wifi密码


/*OneNet*/
PubSubClient mqttClient;
const char* mqttServer = "183.230.40.39";//mqtt服务器
const uint16_t mqttPort = 6002;       //端口号
#define onenet_productId   "466002" //需要修改产品ID
#define onenet_deviceId    "804892296" //需要修改设备ID
#define onenet_apiKey      "EQbaLsJlXRaIG8gD7w5Dsc6i3hc=" //需要修改API_KEY

int state;
Ticker delayTimer;
WiFiClient espClient;
dht11 DHT11;


/* 初始化ONENET通信 */
void initOneNetMqtt() {
  mqttClient.setServer(mqttServer, mqttPort);
  mqttClient.setClient(espClient);
  mqttClient.setCallback(callback);
}


/* 初始化 */
void setup() {
  initSystem();
  initOneNetMqtt();
}

/* 主函数 */
void loop() {
  ESP.wdtFeed();
  DHT11.read(DHT11PIN);
  state = connectToOneNetMqtt();
  Serial.println(WiFi.status());
  if (state == ONENET_RECONNECT) {
    mqttClient.loop();
  }
  else if (state == ONENET_CONNECTED) {
    printf("temp:%d \r\n", DHT11.temperature);
    printf("humi:%d \r\n", DHT11.humidity);
    Temp_pubMQTTmsg(DHT11.temperature);
    Humi_pubMQTTmsg(DHT11.humidity);
    mqttClient.loop();
  }
  delay(2000);
}

OneNet代码如下

/**
 * The blue LED on the ESP-01 module is connected to GPIO1
   初始化系统、连接OneNet、云端下发、发布温湿度信息
*/

/* 初始化系统 */
void initSystem() {
  int cnt = 0;
  Serial.begin (115200);
  Serial.println("\r\n\r\nStart ESP8266 MQTT");
  Serial.print("Firmware Version:");
  Serial.println(VER);
  Serial.print("SDK Version:");
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, HIGH);
  Serial.println(ESP.getSdkVersion());

  ESP.wdtEnable(5000);

  if (WIFI_DEBUG == 1) //开启一键配网模式
  {
    if (!autoConfig())
    {
      Serial.println("Start smartConfig");
      smartConfig();
    }
  }
  else
  {
    WiFi.begin(AP_SSID, AP_PSW);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      cnt++;
      Serial.print(".");
      if (cnt >= 40) {
        cnt = 0;
        //重启系统
        delayRestart(1);
      }
    }
  }
  Serial.print("WIFI Connect \r\n");
}

/* 连接OneNet */
int connectToOneNetMqtt() {
  int cnt = 0;
  while (!mqttClient.connected()) {
    ESP.wdtFeed();
    cnt++;
    Serial.println("Connect to OneNet MQTT...");

    if (mqttClient.connect(onenet_deviceId, onenet_productId, onenet_apiKey)) {
      Serial.println("connect success!");
      return ONENET_RECONNECT;
    } else {
      Serial.print("connect fail!");
      Serial.println(" try again in 5 seconds");
      delayNs(5);
    }
    if (cnt >= 10) {
      //只做10次连接到OneNet，连接不上重启8266
      cnt = 0;
      delayRestart(1);
    }
  }
  return ONENET_CONNECTED;
}

/* 云端下发 */
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  if ((char)payload[0] == '1') {
    digitalWrite(LED_BUILTIN, LOW);
  } else {
    digitalWrite(LED_BUILTIN, HIGH);
  }
}

/* 发布温度信息 */
void Temp_pubMQTTmsg(uint32_t data) {
  long lastMsg = 0;

  char msg[50];
  char tmp[28];
  char d[3];
  snprintf(tmp, sizeof(tmp), "{\"Temp\":%d}", data);
  uint16_t streamLen = strlen(tmp);

  d[0] = '\x03';
  d[1] = (streamLen >> 8);
  d[2] = (streamLen & 0xFF);
  snprintf(msg, sizeof(msg), "%c%c%c%s", d[0], d[1], d[2], tmp);
  mqttClient.publish("$dp", (uint8_t*)msg, streamLen + 3, false);
}
/* 发布湿度信息 */
void Humi_pubMQTTmsg(uint32_t data) {
  long lastMsg = 0;

  char msg[50];
  char tmp[28];
  char d[3];
  snprintf(tmp, sizeof(tmp), "{\"Humi\":%d}", data);
  uint16_t streamLen = strlen(tmp);

  d[0] = '\x03';
  d[1] = (streamLen >> 8);
  d[2] = (streamLen & 0xFF);
  snprintf(msg, sizeof(msg), "%c%c%c%s", d[0], d[1], d[2], tmp);
  mqttClient.publish("$dp", (uint8_t*)msg, streamLen + 3, false);
}

smartConfig 代码如下


/**
 * The blue LED on the ESP-01 module is connected to GPIO1
   自动连接、一键配网、延时重启
*/

/* 自动连接 */
bool autoConfig()
{
  delay(2000);
  for (int i = 0; i < 20; i++)
  {
    Serial.println("Setup start");
    //启动STA模式，并连接到wifi网络
    WiFi.begin(AP_SSID, AP_PSW);
    Serial.print(String("Connecting to ") + AP_SSID);
    if (WiFi.status() == WL_CONNECTED)
    {
      Serial.println("AutoConfig Success");
      Serial.printf("SSID:%s\r\n", WiFi.SSID().c_str());
      Serial.printf("PSW:%s\r\n", WiFi.psk().c_str());
      WiFi.printDiag(Serial);
      return true;
    }
    else
    {
      Serial.print("AutoConfig Waiting......");
      Serial.println(WiFi.status());
      delay(5000);
    }
  }
  Serial.println("AutoConfig Faild!" );
  return false;
}

/* 一键配网 */
void smartConfig()
{
  WiFi.mode(WIFI_STA);
  Serial.println("\r\nWait for Smartconfig");
  WiFi.beginSmartConfig();
  while (1)
  {
    Serial.print(".");
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    if (WiFi.smartConfigDone())
    {
      Serial.println("SmartConfig Success");
      Serial.printf("SSID:%s\r\n", WiFi.SSID().c_str());
      Serial.printf("PSW:%s\r\n", WiFi.psk().c_str());
      WiFi.setAutoConnect(true);  // 设置自动连接
      break;
    }
    delay(2000); // 这个地方一定要加延时，否则极易崩溃重启
  }
}

/* 延时N秒 */
void delayNs(uint8_t m) {
  for (uint8_t index = 0; index < m; index ++) {
    delay(1000);
    ESP.wdtFeed();
  }
}


/* 延时重启 */
void delayRestart(float t) {
  Serial.print("Restart after ");
  Serial.print(t);
  Serial.println("s");
  delayTimer.attach(t, []() {
    Serial.println("\r\nRestart now!");
    ESP.restart();
  });
}

  1. 选择NodeMCU1.0，端口选对应的，其他默认，最后点击上传；
    在这里插入图片描述

  2. 上传成功，点击串口监视器
    在这里插入图片描述

  3. Arduino串口打印显示，onenet平台显示设备在线，点击详情，选择数据流展示可见温湿度数据
    在这里插入图片描述
    在这里插入图片描述
    在这里插入图片描述
    记录这两个变量名称，Humi是湿度，Temp是温度，后面两者有交互

Humi
Temp

3.3 onenet平台交互显示开发

  1. 选择数据模板，添加humi数据流模板
    在这里插入图片描述
    添加Temp数据流模板
    在这里插入图片描述

  2. 选择触发器管理，添加触发器
    在这里插入图片描述

  3. 选择应用管理，添加应用
    在这里插入图片描述

  4. 然后双击lab，进行应用控制设计
    在这里插入图片描述
    在这里插入图片描述
    进行以上操作后点击右上角保存和发布，然后选择应用管理刷新，就可以看见温湿度的动态变化🎉🎉🎉
    在这里插入图片描述
    我自己在尝试其他的拓展，显示效果如下

在这里插入图片描述

4. 总结

  • 本文是一个难度中等的物联网项目，实现ESP8266一键配网功能、MQTT协议连接ONENET、DHT11温湿度数据的获取、数据上发ONENET平台、ESP8266板载LED亮灭的控制、温度限幅触发器提示
  • 在以后的博文中我们将学会用ESP8266做常用的物联网开发，从而实现对外部世界进行感知，充分认识这个有机与无机的环境，科学地合理地进行创作和发挥效益，然后为人类社会发展贡献一点微薄之力。
  • 参考链接：
    第一个链接十分有用，主要参考代码
    ESP8266通过MQTT协议连接ONENET
    玩转 ESP32 + Arduino (十二) 通过MQTT协议上传数据至OneNet云平台

版权声明：本文为CSDN博主「2345VOR」的原创文章，遵循CC 4.0 BY-SA版权协议，转载请附上原文出处链接及本声明。
原文链接：https://blog.csdn.net/vor234/article/details/121109337

标签： · · ·
生成海报
点击下载海报
加载中
点赞 0

创世纪

单片机学习，电子制作DIY学习与分享，各种新鲜的，有趣的，好玩的，一起来吧！机器人、无人机、树莓派/Raspberry Pi、arduino、极客、创客等

暂无评论

发表评论

相关推荐

基于8051单片机实现电子时钟+数字秒表设计
单片机 2022-05-15

基于8051单片机实现电子时钟+数字秒表设计

概述 电子时钟是一种利用数字电路来显示秒、分、时的计时装置，与传统的机械钟相比，它具有走时准确、显 示直观、无机械传动装置等优点，因而得到广泛应用。随着人们生活环境的不断改善和美化，在许

ESP32-GY_30光照强度传感器
单片机 2024-12-19

ESP32-GY_30光照强度传感器

GY_30光照强度传感器介绍 GY-30光强传感器特点及使用介绍 一、连接引脚 GY_30光照强度传感器使用I2C传输数据 。 5根引脚，名称与功能如下; vcc 为外接供电电源输入端 GND 地线 SCL I2C通信模式时钟

汽车级MCU大战“一触即发”
单片机 2024-12-15

汽车级MCU大战“一触即发”

汽车行业，尤其是智能汽车赛道，不仅仅只有高算力SoC。数据显示，汽车微控制器（MCU）市场在过去的十年里占据所有行业MCU总销量的40%。 台积电在去年披露的数据吸纳是&#

LORA电能表在变电所场合的应用
单片机 2024-12-12

LORA电能表在变电所场合的应用

安科瑞 王冲 摘要：在科技发达的今天，电能依旧是国家发展、社会稳定的重要来源。电力配电快速成长，也带来许多问题。在电表安装地点分布广，或布线紧密情况下，传统的有线通讯方式是

分享到：